Présentation

Objectif

LinkedMDB est une base de données du web sémantique ouverte consacrée aux films. Elle contient un grand nombre de connections vers des ensembles de données ouverts et des références vers des pages web connexes.

Données exposées

Les données exposées par LinkedMDB sont toutes les entités liées aux films. On trouve par exemple les acteurs, les directeurs de la photographie, les réalisateurs, les scénaristes, les festivals cinématographiques, etc.

Il est possible parcourir l’ensemble des données de chaque entité. Par exemple, l’URL de l’entité acteur est la suivante : http://data.linkedmdb.org/directory/actor. Cette page offre un aperçu (liste de liens) de tous les acteurs recensés dans LinkedMDB. En cliquant sur le nom d’un acteur, on a alors accès à la page représentant son identité unique. Elle contient des propriétés telles que son nom, les films dans lesquels il a joué ou encore ses performances.

Exemple

Prenons l’exemple du film The Shining. LinkedMDB fournit un grand nombre d’informations sur ce film tels que les acteurs, le réalisateur, la date de réalisation, etc. Toutes ces informations sont disponibles sur le lien suivant : http://data.linkedmdb.org/page/film/2014 sous forme de clé / valeur. L’utilisateur a alors accès à une liste de propriétés et aux valeurs correspondantes. Par exemple, la première ligne du résultat indique que l’acteur numéro 29704 a joué dans ce film. En cliquant sur le lien, on accède aux informations de l’acteur, Jack Nicholson.

Ontologies utilisées

LinkedMDB utilise l’ontologie Movie (MO) et l’ontogolie Friend Of A Friend (FOAF).

L’ontologie Movie fournit un vocabulaire permettant de décrire de façon sémantique les concepts liés aux films et les individus correspondants. Cette ontologie est décrite grâce au langage OWL. Voici quelques exemples issus de l’ontologie Movie :

• is movie:actor of
• is movie:director of
• movie:performance
• movie:actor_actorid
• movie:actor_name

L’ontologie FOAF fournit un vocabulaire permettant de décrire les termes liés aux personnes. Dans LinkedMDB, on retrouve par exemple la propriété “foaf:page” qui renvoie une page ou un document à propos de l’objet étudié. Par exemple, la propriété “foaf:page” de l’acteur Jack Nicholson vaut http://www.freebase.com/guid/9202a8c04000641f800000000004b545, qui est la page web de Freebase dédié à l’acteur.

Sites connectés

LinkedMDB est utilisé par plusieurs sites web sur le cinéma. Parmi les plus connus, on retrouve IMDb, Rotten Tomatoes et Freebase.

IMDb est une base de données en ligne sur le cinéma mondial et la télévision. Ce site internet recense un grand nombre de films et offre toutes sortes d’informations à leur sujet (acteurs, réalisateur, synopsis, critiques, etc.).

Rotten Tomatoes est un site web regroupant des critiques et des informations variées sur les films (et la télévision).

Freebase est une base de données collaborative rassemblant des connaissances du web sous forme sémantique. Elle contient des personnes, lieux et objets célèbres.

Pour reprendre l’exemple de The Shining, IMDb présente les informations relatives à ce film sous une forme plus lisible pour les utilisateurs : http://www.imdb.com/title/tt0081505/.

Adresses du site

Les différentes adresses du site LinkedMDB sont les suivantes :

• RDF (entry point) : http://data.linkedmdb.org/all
• SPARQL endpoint : http://data.linkedmdb.org/sparql.

Exemples de requêtes

Afin de tester LinkedMDB, nous avons réalisé 3 séries de requêtes de plus en plus complexes.

1. Films réalisés par Stanley Kubrick

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?movieName WHERE {
 ?director linkedmdb:director_name "Stanley Kubrick".
 ?movie linkedmdb:director ?director.
 ?movie dc:title ?movieName.
}

2. Acteurs ayant joué dans The Shining.

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?actorName WHERE {
 ?movie dc:title "The Shining".
 ?movie linkedmdb:actor ?actor.
 ?actor linkedmdb:actor_name ?actorName.
}

3. Films réalisés par Stanley Kubrick dans lesquels a joué Jack Nicholson

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?movieName WHERE {
 ?director linkedmdb:director_name "Stanley Kubrick".
 ?actor linkedmdb:actor_name "Jack Nicholson".
 ?movie linkedmdb:director ?director;
 linkedmdb:actor ?actor;
 dc:title ?movieName.
}

4. Films dans lesquels au moins 2 acteurs de The Shining ont joué

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT distinct ?movieName ?actorNameOne ?actorNameTwo WHERE {
 ?movie dc:title "The Shining";
 linkedmdb:actor ?actorOne;
 linkedmdb:actor ?actorTwo.
 
 FILTER(?actorOne != ?actorTwo)
 
 ?otherMovie linkedmdb:actor ?actorOne;
 linkedmdb:actor ?actorTwo;
 dc:title ?movieName.
 
 FILTER(?movieName != "The Shining")
 
 ?actorOne linkedmdb:actor_name ?actorNameOne.
 ?actorTwo linkedmdb:actor_name ?actorNameTwo.
}

5. 10 acteurs ayant joués dans un film de George Lucas

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>

SELECT DISTINCT ?actorName WHERE {
 ?cn linkedmdb:director_name "George Lucas".
 ?movie linkedmdb:director ?cn;
   linkedmdb:actor ?actor.
 ?actor linkedmdb:actor_name ?actorName.
}
LIMIT 10

6. Nombre de films de Georges Lucas dans lesquels les acteurs ayant joué dans au moins un de ses films ont joué (10 résultats)

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?actorName (COUNT(?actorName) AS ?count) WHERE {
 ?cn linkedmdb:director_name "George Lucas".
 ?movie linkedmdb:director ?cn;
 linkedmdb:actor ?actor.
 
 ?actor linkedmdb:actor_name ?actorName.
}
GROUP BY ?actorName
LIMIT 10

7. Films de DreamWorks Animation

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?movieName WHERE {
 ?company linkedmdb:production_company_name "DreamWorks Animation".
 ?movie linkedmdb:production_company ?company;
 dc:title ?movieName.
}

8. Films de DreamWorks Animation qui durent plus que 85 minutes

PREFIX linkedmdb: <http://data.linkedmdb.org/resource/movie/>
PREFIX dc: <http://purl.org/dc/terms/>

SELECT ?movieName ?movie_runtime WHERE {
 ?company linkedmdb:production_company_name "DreamWorks Animation".
 ?movie linkedmdb:production_company ?company.
 ?movie linkedmdb:runtime ?movie_runtime.

 FILTER( ?movie_runtime > "85")
 ?movie dc:title ?movieName
}

Chloé BROUZES
Jue WANG
Quancheng ZHAO